基于Arduino实现的摩尔电码收发器设计方案

我们做了一些实验，构思从石器时代开始，了解人类交流的需求以及交流过程中语言和语法的含义，还有什么是可靠的交流、信号、消息等。

在讨论这些东西时，我们达到了最终能够定义语言交流的地步，与此同时摩尔斯电码应运而生。

很明显，学习摩尔斯电码对我们每个人来说都是一项乏味的任务，因此我们需要一台机器。所以，我们决定编写可以将给定字符串编码为等效摩尔斯电码的小程序和另一个可以将字符串返回给给定摩尔斯码流的解码器。

为了找到一个字符的摩尔斯电码，我参考了下表——

要将摩尔斯电码转换为等效字符，可以将其组织成如下二叉树。每个“点”移动到左子树，“破折号”移动到右子树。

这样的话我就能够快速将字符串编码为相应的摩尔斯电码，反之亦然。

我用 C# 编写了一个程序作为 PoC

输出

由于必须在两方之间进行通信，因此我想将此编码的摩尔斯电码传输到另一个设备并在那里对其进行解码。

所以我使用了两个 Arduino 板来构建发射器和接收器。

在发射器板上，我连接了Keyes 的激光二极管。对于我工作的距离，3v 输入绰绰有余，如果使用 5v 的电压，至少达到 200m的距离。

我的发射器通过串行接口（通过 USB）连接到计算机。它逐个字符地读取串行端口上的任何数据。找到字符的等效摩尔斯电码并生成“点”和“破折号”光流。

我创建了一个 50 ms的脉冲，其中每个“点”是一个 50 ms的光束，一个“破折号”是 150 ms的光束。每个“点”和“破折号”由 50 ms的静音隔开。

发射机代码

const char* MorseTable[] = {
NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL,
NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL,
NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL,
NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL,
// space, !, ", #, $, %, &, '
NULL, "-.-.--", ".-..-.", NULL, NULL, NULL, NULL, ".----.",
// ( ) * + , - . /
"-.--.", "-.--.-", NULL, ".-.-.", "--..--", "-....-", ".-.-.-", "-..-.",
// 0 1 2 3 4 5 6 7
"-----", ".----", "..---", "...--", "....-", ".....", "-....", "--...",
// 8 9 : ; < = > ?
"---..", "----.", "---...", "-.-.-.", NULL, "-...-", NULL, "..--..",
// @ A B C D E F G
".--.-.", ".-", "-...", "-.-.", "-..", ".", "..-.", "--.",
// H I J K L M N O
"....", "..", ".---", "-.-", ".-..", "--", "-.", "---",
// P Q R S T U V W
".--.", "--.-", ".-.", "...", "-", "..-", "...-", ".--",
// X Y Z [ \ ] ^ _
"-..-", "-.--", "--..", NULL, NULL, NULL, NULL, "..--.-",
// ' a b c d e f g
NULL, ".-", "-...", "-.-.", "-..", ".", "..-.", "--.",
// h i j k l m n o
"....", "..", ".---", "-.-", ".-..", "--", "-.", "---",
// p q r s t u v w
".--.", "--.-", ".-.", "...", "-", "..-", "...-", ".--",
// x y z { | } ~ DEL
"-..-", "-.--", "--..", NULL, NULL, NULL, NULL, NULL,
};
int dotLength = 50;
int dashLength = dotLength*3;
void setup() {
// put your setup code here, to run once:
pinMode(13, OUTPUT);
Serial.begin(9600);
}
void loop() {
char ch;
if(Serial.available()){
ch = Serial.read();
flashDashDot(MorseTable[ch]);
delay(dotLength*2);
}
}
void flashDashDot(const char * morseCode)
{
int i = 0;
while(morseCode[i] != 0)
{
if(morseCode[i] == '.'){
dot();
} else if (morseCode[i] == '-'){
dash();
}
i++;
}
}
void dot()
{
digitalWrite(13, HIGH);
delay(dotLength);
digitalWrite(13, LOW);
delay(dotLength);
}
void dash()
{
digitalWrite(13, HIGH);
delay(dashLength);
digitalWrite(13, LOW);
delay(dotLength);
}

在接收器 Arduino 板上，我连接了LDR 、压电蜂鸣器和LED 。LED 和蜂鸣器是多余的，只是它们提供音频和视频反馈，能够使我们知会到系统正在正常工作。

我的接收器还连接到计算机以读取生成的字符串字符。

在设备上的一个循环中，我读取了照射到连接到模拟端口 4 的 LDR 的光，我用了一根长管将其与任何环境光隔离开来。当我的激光二极管发出的光照射到这个 LDR 上时，结果值变高，接着打开扬声器并打开 LED。当它下降时，我打开扬声器并关闭LED。

我正在计算光束的长度以确定它是“点”还是“破折号”。考虑到所有延迟，我的 16MHz Atmel 处理器上的一个脉冲大约需要 400 个周期。

接收设备代码

const char MorseTree[] = {'\0','E', 'T', 'I', 'A', 'N', 'M', 'S',
'U', 'R', 'W', 'D', 'K', 'G', 'O', 'H',
'V', 'F', 'U', 'L', 'A', 'P', 'J', 'B',
'X', 'C', 'Y', 'Z', 'Q', '\0','\0','5',
'4', '\0','3', '\0','\0','\0','2', '\0',
'\0','+', '\0','\0','\0','\0','1', '6',
'=', '/', '\0','\0','\0','(', '\0','7',
'\0','\0','\0','8', '\0','9', '0', '\0',
'\0','\0','\0','\0','\0','\0','\0','\0',
'\0','\0','\0','?', '_', '\0','\0','\0',
'\0','"', '\0','\0','.', '\0','\0','\0',
'\0','@', '\0','\0','\0','\0','\0','\0',
'-', '\0','\0','\0','\0','\0','\0','\0',
'\0',';', '!', '\0',')', '\0','\0','\0',
'\0','\0',',', '\0','\0','\0','\0',':',
'\0','\0','\0','\0','\0','\0','\0'
};
int val = 0; // A Variable to Store the Light Value from the LDR
int ctrHigh = 0;
int ctrLow = 0;
int codePtr = 0;
int dotLen = 400;
void setup()
{
Serial.begin(9600);// Start a Serial Connection
Serial.print(codePtr);
}
void loop()
{
val = analogRead(4);
if (val >= 10)
{
ctrHigh++;
ctrLow = 0;
digitalWrite(13, HIGH);
tone(9, 1000);
} else {
ctrLow++;
if ((ctrHigh >= dotLen) && (ctrHigh < dotLen*2)) {
Serial.print(".");
codePtr = (2*codePtr) + 1;
} else if (ctrHigh >= dotLen * 2) {
Serial.print("-");
codePtr = (2*codePtr) + 2;
} else {
if(ctrLow == dotLen*2){
Serial.print(MorseTree[codePtr]);
codePtr = 0;
}
}
ctrHigh = 0;
digitalWrite(13, LOW);
noTone(9);
}
}