红外线遥控器解码程序

红外线遥控器解码程序

红外线遥控是目前使用最广泛的一种通信和遥控手段。由于红外线遥控装置具有体积小、功耗低、功能强、成本低等特点，因而，继彩电、录像机之后，在录音机、音响设备、空凋机以及玩具等其它小型电器装置上也纷纷采用红外线遥控。工业设备中，在高压、辐射、有毒气体、粉尘等环境下，采用红外线遥控不仅完全可靠而且能有效地隔离电气干扰。

1 红外遥控系统

通用红外遥控系统由发射和接收两大部分组成，应用编/解码专用集成电路芯片来进行控制操作，如图1所示。发射部分包括键盘矩阵、编码调制、LED红外发送器；接收部分包括光、电转换放大器、解调、解码电路。

2 遥控发射器及其编码

遥控发射器专用芯片很多，根据编码格式可以分成脉冲宽度调制和脉冲相位调制两大类，这里我们以运用比较广泛，解码比较容易的脉冲宽度调制来加以说明，现以LC7461组成发射电路为例说明编码原理。当发射器按键按下后，即有遥控码发出，所按的键不同遥控编码也不同。这种遥控码具有以下特征：

采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的“0”；以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的“1”

上述“0”和“1”组成的42位二进制码经38kHz的载频进行二次调制以提高发射效率，达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射，

7461产生的遥控编码是连续的42位二进制码组，其中前26位为用户识别码，能区别不同的红外遥控设备，防止不同机种遥控码互相干扰。后16位为8位的操作码和8位的操作反码用于核对数据是否接收准确。

当遥控器上任意一个按键按下超过36ms时，LC7461芯片的振荡器使芯片激活，将发射一个特定的同步码头，对于接收端而言就是一个9ms的低电平,和一个4.5ms的高电平，这个同步码头可以使程序知道从这个同步码头以后可以开始接收数据。

解码的关键是如何识别“0”和“1”，从位的定义我们可以发现“0”、“1”均以0.56ms的低电平开始，不同的是高电平的宽度不同，“0”为0.56ms,“1”为1.68ms,所以必须根据高电平的宽度区别“0”和“1”。如果从0.56ms低电平过后，开始延时，0.56ms以后，若读到的电平为低，说明该位为“0”，反之则为“1”，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为“0”，读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右即可。

根据红外编码的格式，程序应该等待9ms的起始码和4.5ms的结果码完成后才能读码。

接收器及解码

LT0038是塑封一体化红外线接收器，它是一种集红外线接收、放大、整形于一体的集成电路，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，没有红外遥控信号时为高电平，收到红外信号时为低电平，而体积和普通的塑封三极管大小一样，它适合于各种红外线遥控和红外线数据传输。

下面是一个对启点开发板配套的红外线遥控器的解码程序，它可以把试验板佩戴的32键的红外遥控器每一个按键的键值读出来，并且通过实验板上P1口的8个LED显示出来，在解码成功的同时并且能发出“嘀嘀嘀”的提示音。

MCS51单片机汇编程序

        ORG 0000H
        AJMP MAIN     ;转入主程序
        ORG 0003H     ;外部中断P3.2脚INT0入口地址
        AJMP INT      ;转入外部中断服务子程序（解码程序）
        ;以下为主程序进行CPU中断方式设置
MAIN:   SETB EA       ;打开CPU总中断请求
        SETB IT0      ;设定INT0的触发方式为脉冲负边沿触发
        SETB EX0      ;打开INT0中断请求
        ;以下对单片机的所有引脚进行初始化，全部设置成高电平
        MOV P2,#11100111B
        AJMP $
        ;以下为进入P3.2脚外部中断子程序，也就是解码程序
INT:    CLR EA        ;暂时关闭CPU的所有中断请求
        MOV R6,#10
SB:     ACALL YS1     ;调用882微秒延时子程序
        JB P3.2,EXIT  ;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
        DJNZ R6, SB   ;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
        ;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
        JNB P3.2, $   ;等待高电平避开9毫秒低电平引导脉冲
        ACALL YS2     ;延时4.74毫秒避开4.5毫秒的结果码
        MOV R7,#26    ;忽略前26位系统识别码
JJJJA:  JNB P3.2,$    ;等待地址码第一位的高电平信号
        LCALL YS1     ;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
        MOV C,P3.2    ;将P3.2引脚此时的电平状态0或1存入C中
        JNC UUUA      ;如果为0就跳转到UUUA
        LCALL YS3     ;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUUA:   DJNZ R7,JJJJA
        MOV R1,#1AH   ;设定1AH为起始RAM区
        MOV R2,#2     ;接收从1AH到1BH的2个内存,用于存放操作码和操作反码
PP:     MOV R3,#8     ;每组数据为8位
JJJJ:   JNB P3.2,$    ;等待地址码第一位的高电平信号
        LCALL YS1     ;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
        MOV C,P3.2    ;将P3.2引脚此时的电平状态0或1存入C中
        JNC UUU       ;如果为0就跳转到UUU
        LCALL YS3     ;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUU:    MOV A,@R1     ;将R1中地址的给A
        RRC A         ;将C中的值0或1移入A中的最低位
        MOV @R1,A     ;将A中的数暂时存放在R1数值的内存中
        DJNZ R3,JJJJ  ;接收满8位换一个内存
        INC R1        ;对R1中的值加1，换下一个RAM
        DJNZ R2,PP    ;接收完8位数据码和8位数据反码，存放在1AH/1BH中
        MOV A,1AH
        CPL A         ;对1AH取反后和1BH比较
        CJNE A,1BH,EXIT       ;如果不等表示接收数据发生错误,放弃
        MOV P1,1AH    ;将按键的键值通过P1口的8个LED显示出来!
        SETB P3.5     ;蜂鸣器鸣响－嘀嘀嘀－的声音，表示解码成功
        LCALL YS2
        LCALL YS2
        LCALL YS2
        CLR P3.5      ;蜂鸣器停止
EXIT:   SETB EA       ;允许中断
        RETI          ;退出解码子程序
YS1:    MOV R4,#20    ;延时子程序1，精确延时882微秒
D1:     MOV R5,#20
        DJNZ R5,$
        DJNZ R4,D1
        RET
YS2:    MOV R4,#10    ;延时子程序2，精确延时4740微秒
D2:     MOV R5,#235
        DJNZ R5,$
        DJNZ R4,D2
        RET
YS3:    MOV R4,#2     ;延时程序3，精确延时1000微秒
D3:     MOV R5,#248
        DJNZ R5,$
        DJNZ R4,D3
        RET
        END