20bps数字数据无线收发器

描述

 

比特流与摩尔斯电码

 

介绍

在我的数字通信课上，我试图通过发现领域问题并解决它们来帮助我的学生学习数字通信/计算机网络。在上一节课中，我们使用激光和 LDR构建了一个摩尔斯电码发射器/接收器。

今天，我将其扩展到传输数字数据；以0和1的流编码的数据。在摩尔斯电码中，'dot'和'dash'相当于数字数据的0和1。但是，我们有 0/点的明确信号。没有信号不被解释为零。这使得渠道成本更高。我可以达到每分钟约 18 个单词（PARIS 通常用作此计算的参考单词）。这相当于每分钟 75 个字节或10bps 。

发射机

由于我的发射器是一个具有开和关状态的激光二极管，关闭状态可以被认为是 0，而打开状态可以被认为是 1。然而，这提出了一个挑战，即如何区分代表数据的一组 0 和0代表静默（没有数据传输）。

编辑代码

由于我们遇到了这个问题，我添加了一个开始消息头/模式 (1011) 和一个结束消息头/模式 (1101)。我不断地在我的 LDR 接收器上采样数据，并将读取值 0/1 添加到我的数据中。然后，我检查结束模式，如果找到，我检查 8 位数据之前的起始标头。

1011 <8 位数据> 1101

H: 1011010010001101
E: 1011010001011101
L: 1011010011001101
L: 1011010011001101
O: 1011010011111101

我可以在我的接收器上解码这个模式。

 

解码消息

 

然而，这种封装消息的简单模式并非万无一失。它很容易被流氓数据系列破解。

 

带有垃圾数据的解码消息

 

那么如何验证接收到的数据是否真的是另一端发送的数据呢？

我在数据末尾添加了一个小签名；设置位数。由于我的数据是 8 位，我又添加了 4 位来表示可以在数据中设置的最多 8 位。

1011 <8_bit_data><4_sign_bits> 1101

H: 10110100100000101101
E: 10110100010100111101
L: 10110100110000111101
L: 10110100110000111101
O: 10110100111101011101

我也可以解码这个模式。结果，我可以过滤掉一些垃圾：

 

没有垃圾的解码消息

 

我确实有数据丢失，但现在垃圾更少了。那么我该如何进一步改进呢？我可以修复传输错误吗？我可以更好地利用符号位吗？大量可能的改进，但当我们遇到问题并且我们确信该问题值得解决时，我们将解决。可能是下节课……

发射机：

#define PULSE 50
#define START_MSG one(); zero(); one(); one();
#define   END_MSG one(); one(); zero(); one();
#define MSG_PACK(x) START_MSG x END_MSG
void setup() {
  pinMode(13, OUTPUT);
}
void loop() {
  // <8_Data_Bits><4_Sign_Bits>
  //H: 2 set bits
  MSG_PACK(zero(); one(); zero(); zero(); one(); zero(); zero(); zero(); \
           zero(); zero(); one(); zero(); )
  //E: 3 set bits
  MSG_PACK(zero(); one(); zero(); zero(); zero(); one(); zero(); one(); \
           zero(); zero(); one(); one(); )
  //L: 3 set bits
  MSG_PACK(zero(); one(); zero(); zero(); one(); one(); zero(); zero(); \
           zero(); zero(); one(); one(); )
  //L: 3 set bits
  MSG_PACK(zero(); one(); zero(); zero(); one(); one(); zero(); zero(); \
           zero(); zero(); one(); one(); )
  //O: 5 set bits
  MSG_PACK(zero(); one(); zero(); zero(); one(); one(); one(); one(); \
           zero(); one(); zero(); one(); )
  //CR: 3 set bits
  MSG_PACK(zero(); zero(); zero(); zero(); one(); one(); zero(); one(); \
           zero(); zero(); one(); one(); )
  //LF: 2 set bits
  MSG_PACK(zero(); zero(); zero(); zero(); one(); zero(); one(); zero(); \
           zero(); zero(); one(); zero(); )
}
void zero()
{
  digitalWrite(13, LOW);
  delay(PULSE);
}
void one()
{
  digitalWrite(13, HIGH);
  delay(PULSE);
} 

接收者：

#define SOM 0xB
#define EOM 0xD
#define PULSE 50
unsigned long data = 0; 
void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
}
void loop() {
  // put your main code here, to run repeatedly:
  int val = analogRead(4);
  unsigned long sign = 0;
  data = (data << 1);
  if(val >= 10){
    data |= 1;
  }else {
    data |= 0;
  }
  //check tail signature
  if(EOM == (data&EOM))
  {
    //check head signature
    if(SOM == ((data >> 16)&0xF)){
      sign = (data>>4)&0xF; // 4 bits of signature
      data = (data>>8)&0xFF;// 8 bits of data
      if(sign == getSetBits(data))
      {
        Serial.print((char)data);
      }
      //Diagnostics
      //if(data==72||data==69||data==76||data==79||data==13||data==10){
        //data
        //digitalWrite(13, HIGH);
      //}else{
        //error
        //digitalWrite(12, HIGH);
      //}
      data = 0;
    }
  }
  delay(PULSE);
  //digitalWrite(13, LOW);
  //digitalWrite(12, LOW);
}
unsigned long getSetBits(unsigned long n)
{
  unsigned long count = 0;
  while(n)
  {
    n &= (n-1);
    count++;
  }
  return count;
} 

顺便说一句，我使用此处发布的最终代码实现了每秒约 1 字节数据的速度。包括标头在内，达到每秒 20 位！

编辑

为了检测数据中的错误，我在数据中添加设置位数的签名机制并没有被证明是好的。我需要一个不会增加大量数据开销的更好、更便宜的解决方案。

I XOR 高半字节和低半字节以生成 4 位签名。此签名不太可能失败，因为错误（位翻转）必须发生在高半字节和低半字节的相应位上。

// (sign == (right ^ left))
if(sign == ((data & 0xF) ^ ((data >> 4) & 0xF))){
       Serial.print((char)data);
}

正如预期的那样，结果比以前更好。我很少看到恶意字节通过此测试。

 

XOR 签名的结果

 

在理想情况下，我不会出错。我还没有看到流氓字节，但我确实看到数据包被丢弃了。我如何确保以正确的顺序收到所有数据？

这是下一个要解决的问题。为每个数据包构建一个 ACK​​，以便发送方可以确认他发送的内容确实已收到。我计划发回收到的异或符号。但是我没有其他激光二极管用于此目的...